source: trunk/m4/mysql.m4 @ 704

# Copyright (C) 2005-2008 David Carter <arm4@arm4.org>
#  
# This file is free software; as a special exception the author gives
# unlimited permission to copy and/or distribute it, with or without 
# modifications, as long as this notice is preserved.
# 
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

# Macros to check the version for the MySql library, and to set whatever link flags are appropriate

AC_DEFUN([__ARM4_MYSQL_CHECK_VERSION],
[
  min_mysql_version=ifelse([$1], ,5.0,$1)
  mysql_config="$2"

  no_mysql=""
  AC_MSG_CHECKING(for mysql - version >= $min_mysql_version)
  mysql_major_version=`$mysql_config --version | \
             sed 's/^[[A-Za-z :]]*\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\).*/\1/'`
  if test "x${mysql_major_version}" = "x" ; then
           mysql_major_version=0
  fi
        
  mysql_minor_version=`$mysql_config --version | \
             sed 's/^[[A-Za-z :]]*\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\).*/\2/'`
  if test "x${mysql_minor_version}" = "x" ; then
           mysql_minor_version=0
  fi
        
  mysql_micro_version=`$mysql_config --version | \
             sed 's/^[[A-Za-z :]]*\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\).*/\3/'`
  if test "x${mysql_micro_version}" = "x" ; then
           mysql_micro_version=0
  fi
        
  rm -f conf.sqlitetest
  AC_RUN_IFELSE([
#include <stdio.h>
#include <stdlib.h>
#include <string.h>

char* my_strdup (const char *str);

char*
my_strdup (const char *str)
{
  char *new_str;
  
  if (str)
    {
      new_str = (char *)malloc ((strlen (str) + 1) * sizeof(char));
      strcpy (new_str, str);
    }
  else
    new_str = NULL;
  
  return new_str;
}

int main (void)
{
  int major = 0, minor = 0, micro = 0;
  int n;
  char *tmp_version;

  system ("touch conf.sqlitetest");

  /* HP/UX 9 (%@#!) writes to sscanf strings */
  tmp_version = my_strdup("$min_mysql_version");

  n = sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) ;

  if (n != 2 && n != 3) {
     printf("%s, bad version string\n", "$min_mysql_version");
     exit(1);
   }

   if (($mysql_major_version > major) ||
      (($mysql_major_version == major) && ($mysql_minor_version > minor)) ||
      (($mysql_major_version == major) && ($mysql_minor_version == minor) && ($mysql_micro_version >= micro)))
    {
      exit(0);
    }
  else
    {
      printf("\n*** 'mysql -version' returned %d.%d.%d, but the minimum version\n", $mysql_major_version, $mysql_minor_version, $mysql_micro_version);
      printf("*** of mysql required is %d.%d.%d. If mysql is correct, then it is\n", major, minor, micro);
      printf("*** best to upgrade to the required version.\n");
      exit(1);
    }
}

],, no_mysql=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])

  if test "x$no_mysql" = x ; then
    AC_MSG_RESULT(yes)
  else
    AC_MSG_ERROR([mysql version $min_mysql_version or greater is required])
  fi
])

AC_DEFUN([ARM4_VERSION_MYSQL],
[
  min_mysql_version=ifelse([$1], ,5.0,$1)

  AC_MSG_CHECKING(for MySQL configuration)
  mysql_found="no"
  mysql_config=""
  AC_ARG_WITH(mysql,
  [  --with-mysql=PATH       path to the mysql_config script],
  [
    if test "$withval" = "no" || test "$withval" = "yes"; then
      AC_MSG_ERROR([--with-mysql requires the path to mysql_config to be provided])
    fi

    if test -x "$withval" > /dev/null 2>&1 ; then
      mysql_found="yes"
      mysql_config="$withval"
    fi

    dnl if --with-mysql is used, it is a fatal error for its argument
    dnl to be invalid
    if test "$mysql_found" != "yes"; then
      AC_MSG_ERROR([the --with-mysql parameter is incorrect. It must specify the path to mysql_config.])
    fi
  ],[
        mysql_path="`which mysql_config`"
    if test -x "$mysql_path" > /dev/null 2>&1 ; then
      mysql_found="yes"
      mysql_config="$mysql_path"
    else
      AC_MSG_ERROR([unable to find mysql_config.])
    fi
  ])
  AC_MSG_RESULT($mysql_found)
  
  if test "$mysql_found" = "yes" ; then
      __ARM4_MYSQL_CHECK_VERSION([$min_mysql_version], [$mysql_config])
      AC_MSG_CHECKING(for mysql flags)
        MYSQL_CFLAGS="`$mysql_config --cflags`"
        AC_SUBST(MYSQL_CFLAGS)
      AC_MSG_RESULT($MYSQL_CFLAGS)
      AC_MSG_CHECKING(for mysql libs)
        MYSQL_LIBS="`$mysql_config --libs_r`"
        AC_SUBST(MYSQL_LIBS)
      AC_MSG_RESULT($MYSQL_LIBS)
  fi
])

AC_DEFUN([ARM4_CHECK_MYSQL],
[
  min_mysql_version=ifelse([$1], ,5.0,$1)

  AC_MSG_CHECKING(for MySQL)
  AC_ARG_ENABLE(mysql,
  [  --enable-mysql          enable MySQL database back end],
  [case "${enableval}" in
     yes) mysql=yes ;;
     no)  mysql=no ;;
     *) AC_MSG_ERROR([bad value ${enableval} for --enable-mysql]) ;;
   esac],
  [mysql=no])
  AC_MSG_RESULT($mysql)
  AM_CONDITIONAL([BUILD_MYSQL], [test "$mysql" = "yes" ])
  if test "$mysql" = "yes" ; then
    ARM4_VERSION_MYSQL([$min_mysql_version])
    AC_DEFINE(HAVE_MYSQL, 1,
      [Define wether the MySql back end is implemented on this platform])
  fi
])