source: trunk/m4/db.m4 @ 704

# Copyright (c) 2005-2008 David Carter <dcarter@arm4.org> and others.
# All rights reserved.   This program and the accompanying materials
# are made available under the terms of the Eclipse Public License v1.0
# which accompanies this distribution, and is available at
# http://www.eclipse.org/legal/epl-v10.html

# Macros to check the version for the Berkeley DB library, and to set whatever link flags are appropriate

AC_DEFUN([__ARM4_DB_CHECKLINK],
[
  DB_LIBS="$1"
  ac_save_LIBS="$LIBS"
  LIBS="$LIBS $DB_LIBS"
  AC_LINK_IFELSE([
#include <db.h>

main ()
{
        DB_ENV  *environment_ptr;
        db_env_create (&environment_ptr, 0);
}
], ,[DB_LIBS=""])
  LIBS="$ac_save_libs"
  AC_SUBST(DB_LIBS)
])

AC_DEFUN([__ARM4_DB_CHECK_DBSTAT],
[
  DB_STAT=""
  AC_MSG_CHECKING(for db_stat)
  AC_ARG_WITH(berkeley-db-stat,
  [  --with-berkeley-db-stat=PATH to the db_stat program],
  [
    if test "$withval" = "no" || test "$withval" = "yes"; then
      AC_MSG_ERROR([--with-berkeley-db-stat requires the path to the db_stat program be provided])
    fi

    if test -x "$withval" > /dev/null 2>&1 ; then
      DB_STAT="$withval"
    fi
  ],
  [
    AC_PATH_PROG(DB_STAT, db_stat, no)
    if test "$DB_STAT" = "no" ; then
      DB_STAT=""
    fi
  ])
  if test "x$DB_STAT" = "x"; then
    AC_MSG_RESULT(no)
  else
    AC_MSG_RESULT(yes)
  fi
  AC_SUBST(DB_STAT)
])

AC_DEFUN([ARM4_VERSION_DB],
[
  min_db_version=ifelse([$1], ,4.1,$1)
  AC_ARG_WITH(berkeley-db,
  [  --with-berkeley-db=PATH prefix for installed Berkeley DB,
                          or the path to the Berkeley DB build tree],
  [
    db_found="no"
    db_root=""
    if test "$withval" = "no" || test "$withval" = "yes"; then
      AC_MSG_ERROR([--with-berkeley-db requires a directory to be provided])
    fi

    if test "$db_found" != "yes" && test -d "$withval" > /dev/null 2>&1 ; then
      db_found="yes"
      db_root="$withval"
    fi

    dnl if --with-berkeley-db is used, it is a fatal error for its argument
    dnl to be invalid
    if test "$db_found" != "yes"; then
      AC_MSG_ERROR([the --with-berkeley-db parameter is incorrect. It must specify an install prefix, or a a build directory.])
    else
      CPPFLAGS="-I$db_root/include $CPPFLAGS"
      AC_MSG_CHECKING(for db flags)
      __ARM4_DB_CHECKLINK([-L$db_root/lib -ldb])
      if test "x$DB_LIBS" = x ; then
        __ARM4_DB_CHECKLINK([-L$db_root/lib -ldb -lpthread])
      fi
      AC_MSG_RESULT($DB_LIBS)
    fi
  ],[
    __ARM4_DB_CHECK_DBSTAT
    AC_MSG_CHECKING(for db - version >= $min_db_version)
    no_db=""
    if test "$DB_STAT" = "no" || test "x$DB_STAT" = "x" ; then
      no_db=yes
    else
      db_major_version=`$DB_STAT -V | \
           sed 's/^[[A-Za-z :]]*\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\).*/\1/'`
      if test "x${db_major_version}" = "x" ; then
         db_major_version=0
      fi

      db_minor_version=`$DB_STAT -V | \
           sed 's/^[[A-Za-z :]]*\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\).*/\2/'`
      if test "x${db_minor_version}" = "x" ; then
         db_minor_version=0
      fi

      db_micro_version=`$DB_STAT -V | \
           sed 's/^[[A-Za-z :]]*\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\)\.\{0,1\}\([[0-9]]*\).*/\3/'`
      if test "x${db_micro_version}" = "x" ; then
         db_micro_version=0
      fi

      enable_dbtest=yes
      if test "x$enable_dbtest" = "xyes" ; then
        rm -f conf.dbtest
        AC_RUN_IFELSE([
#include <stdio.h>
#include <stdlib.h>
#include <string.h>

char* my_strdup (const char *str);

char*
my_strdup (const char *str)
{
  char *new_str;
  
  if (str)
    {
      new_str = (char *)malloc ((strlen (str) + 1) * sizeof(char));
      strcpy (new_str, str);
    }
  else
    new_str = NULL;
  
  return new_str;
}

int main (void)
{
  int major = 0, minor = 0, micro = 0;
  int n;
  char *tmp_version;

  system ("touch conf.dbtest");

  /* HP/UX 9 (%@#!) writes to sscanf strings */
  tmp_version = my_strdup("$min_db_version");

  n = sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) ;

  if (n != 2 && n != 3) {
     printf("%s, bad version string\n", "$min_db_version");
     exit(1);
   }

   if (($db_major_version > major) ||
      (($db_major_version == major) && ($db_minor_version > minor)) ||
      (($db_major_version == major) && ($db_minor_version == minor) && ($db_micro_version >= micro)))
    {
      exit(0);
    }
  else
    {
      printf("\n*** 'db_stat -V' returned %d.%d.%d, but the minimum version\n", $db_major_version, $db_minor_version, $db_micro_version);
      printf("*** of DB required is %d.%d.%d. If db_stat is correct, then it is\n", major, minor, micro);
      printf("*** best to upgrade to the required version.\n");
      exit(1);
    }
}

],, no_db=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
       fi
    fi
    if test "x$no_db" = x ; then
       AC_MSG_RESULT(yes)
       AC_MSG_CHECKING(for db flags)
       __ARM4_DB_CHECKLINK([-ldb])
       if test "x$DB_LIBS" = x ; then
         __ARM4_DB_CHECKLINK([-ldb -lpthread])
       fi
       AC_MSG_RESULT($DB_LIBS)
       ifelse([$2], , :, [$2])     
    else
       AC_MSG_RESULT(no)
       if test "$DB_STAT" = "no" ; then
         echo "*** The db_stat program could not be found"
         echo "*** If DB was installed in PREFIX, make sure PREFIX/bin is in"
         echo "*** your path."
       else
         if test -f conf.dbtest ; then
          :
         else
          echo "*** Could not run DB test program, checking why..."
          AC_LINK_IFELSE([AC_LANG_PROGRAM([[
#include <stdio.h>
]], [[ return 0; ]])],[ echo "*** The test program compiled, but did not run. This usually means"
            echo "*** that the run-time linker is not finding DB or finding the wrong"
            echo "*** version of DB. If it is not finding DB, you'll need to set your"
            echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
            echo "*** to the installed location  Also, make sure you have run ldconfig if that"
            echo "*** is required on your system"
            echo "***"
            echo "*** If you have an old version installed, it is best to remove it, although"
            echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],[ echo "*** The test program failed to compile or link. See the file config.log for the"
            echo "*** exact error that occured. This usually means DB was incorrectly installed"
            echo "*** or that you have moved DB since it was installed. In the latter case, you"
            echo "*** may want to edit the db_stat script: $DB_STAT" ])
         fi
       fi
       ifelse([$3], , :, [$3])
    fi
    rm -f conf.dbtest
  ])
])